<?xml version="1.0" encoding="utf-8"?>

<!--
$Id: index.xsl 9570 2010-03-15 23:21:23Z gawrilow $

This file produces the index.html file of the polymake documentation.

Author: Silke Möser, 2010
-->

<xsl:stylesheet version="1.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:html="http://www.w3.org/1999/xhtml"
	xmlns:pm="http://www.polymake.de/ns/docs#3"
>

<xsl:include href="macros.xsl" />

<xsl:output method="html" 
	doctype-public="-//W3C//DTD HTML 4.01//EN"
	doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>


<xsl:template match="/">
	<html>
	 	
		<head>
			<title>polymake documentation</title>
			<link rel="stylesheet" href="docstyle.css"/>
			<link href="http://www.opt.tu-darmstadt.de/polymake/lib/tpl/default/images/favicon.ico" rel="shortcut icon"/>
		</head>

		<body>

			<!-- header -->
			<div class="header">
				<div class="pageheader">
				[[<span class="pagename">polymake documentation</span>]]
				</div>
			
				<div class="logo">
					<a href="index.html">polymake doku</a>
				</div>
				
				<div class="clearer"/>
			</div>
			
			<!-- navigation box -->
			<div class="nav">
				<div class="navheader">
					Navigation
				</div> 
				<div class="nav_inside">
					<ul class="nav">
						<li> <a href="index.html#apps">applications</a> </li>
						<li> <a href="doc_index.html">index</a> </li>
                                                <li> <xsl:call-template name="wiki-ref"><xsl:with-param name="reftext">polymake wiki</xsl:with-param></xsl:call-template> </li>
					</ul>  
				</div>  
			</div>
		
<!-- content -->
<div class="page">
	<h1>Welcome to the new documentation of <span class="pm">polymake</span></h1>
	
	<p>This documentation constitutes a reference of all functions available in 
        polymake <xsl:apply-templates mode="version" select="document('version.xml')/*"/>.</p>


	<div class="level2">
		<h2><a name="apps">applications</a></h2>
		<ul>
			<xsl:apply-templates select="/pm:applications/pm:file">
				<xsl:sort select="@name"/>
			</xsl:apply-templates>
		</ul>
		
		<h2><a href="doc_index.html">index</a></h2>
		The <a href="doc_index.html">index</a> contains an alphabetical list of all entities (i.e., objects, properties, functions, types and applications) available in your version of polymake.

		<h2><xsl:call-template name="wiki-ref"><xsl:with-param name="reftext">wiki</xsl:with-param></xsl:call-template></h2>
		More detailed information about special topics, as well as howtos and tutorials can be found in (and also - even more importantly -  added to :-) ) the <xsl:call-template name="wiki-ref"><xsl:with-param name="reftext">polymake wiki</xsl:with-param></xsl:call-template>.

	</div>
</div>	

		</body>
		
	</html>
</xsl:template>


<xsl:template match="pm:file">
	<li>
		<a>
			<xsl:attribute name="href"><xsl:value-of select="substring-before(@name,'.')"/>.html</xsl:attribute>

			<xsl:value-of select="substring-before(@name,'.')"/>
		</a>
	</li>
</xsl:template>


<xsl:template mode="version" match="/pm:version">
  <xsl:apply-templates mode="version" select="*" />
</xsl:template>

<xsl:template mode="version" match="pm:revision">
  <xsl:text> extracted from svn snapshot </xsl:text> <xsl:value-of select="normalize-space(current())"/>
</xsl:template>

<xsl:template mode="version" match="pm:release">
  <xsl:text> as of release </xsl:text> <xsl:value-of select="normalize-space(current())"/>
</xsl:template>

<xsl:template mode="version" match="pm:extensions">
  <xsl:text> with following individual extensions: </xsl:text>
  <xsl:for-each select="./pm:extension">
    <br/> <tt> <xsl:value-of select="normalize-space(current())" /> </tt>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>
